Patchwork use AS_HELP_STRING throughout gcc/configure.ac

login
register
mail settings
Submitter Andreas Schwab
Date May 12, 2011, 9:22 a.m.
Message ID <m3fwok6zp7.fsf@redhat.com>
Download mbox | patch
Permalink /patch/95280/
State New
Headers show

Comments

Andreas Schwab - May 12, 2011, 9:22 a.m.
This changes all uses of AC_ARG_(WITH|ENABLE) to use AS_HELP_STRING,
fixing a few quoting bugs on the way.

OK for trunk?

Andreas.

2011-05-12  Andreas Schwab  <schwab@redhat.com>

	* configure.ac: Use AS_HELP_STRING throughout.
	* configure: Regenerate.
Ralf Wildenhues - May 12, 2011, 7:04 p.m.
* Andreas Schwab wrote on Thu, May 12, 2011 at 11:22:12AM CEST:
> This changes all uses of AC_ARG_(WITH|ENABLE) to use AS_HELP_STRING,
> fixing a few quoting bugs on the way.
> 
> OK for trunk?

Yes, if you visually compared the diff of configure and of './configure
--help' before and after the change, to only contain intended changes.
(Which I'm sure you have done.)

Thanks,
Ralf

> 2011-05-12  Andreas Schwab  <schwab@redhat.com>
> 
> 	* configure.ac: Use AS_HELP_STRING throughout.
> 	* configure: Regenerate.
Andreas Schwab - May 13, 2011, 8:13 a.m.
"Ralf Wildenhues" <Ralf.Wildenhues@gmx.de> writes:

> Yes, if you visually compared the diff of configure and of './configure
> --help' before and after the change, to only contain intended changes.

Yes, I did.  The help texts are now nicely aligned and folded, except
for a few which come from outside (more to follow).

Thanks, Andreas.

Patch

diff --git a/gcc/configure.ac b/gcc/configure.ac
index 92d9e29..87b7120 100644
--- a/gcc/configure.ac
+++ b/gcc/configure.ac
@@ -105,7 +105,8 @@  fi
 # Specify the local prefix
 local_prefix=
 AC_ARG_WITH(local-prefix,
-[  --with-local-prefix=DIR specifies directory to put local include],
+[AS_HELP_STRING([--with-local-prefix=DIR],
+		[specifies directory to put local include])],
 [case "${withval}" in
 yes)	AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 no)	;;
@@ -123,8 +124,8 @@  fi
 gcc_gxx_include_dir=
 # Specify the g++ header file directory
 AC_ARG_WITH(gxx-include-dir,
-[  --with-gxx-include-dir=DIR
-                          specifies directory to put g++ header files],
+[AS_HELP_STRING([--with-gxx-include-dir=DIR],
+                [specifies directory to put g++ header files])],
 [case "${withval}" in
 yes)	AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 no)	;;
@@ -145,9 +146,9 @@  if test x${gcc_gxx_include_dir} = x; then
 fi
 
 AC_ARG_WITH(cpp_install_dir,
-[  --with-cpp-install-dir=DIR
-                          install the user visible C preprocessor in DIR
-                          (relative to PREFIX) as well as PREFIX/bin],
+[AC_HELP_STRING([--with-cpp-install-dir=DIR],
+                [install the user visible C preprocessor in DIR
+                 (relative to PREFIX) as well as PREFIX/bin])],
 [if test x$withval = xyes; then
   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 elif test x$withval != xno; then
@@ -163,10 +164,10 @@  fi])
 AC_MSG_CHECKING([whether to place generated files in the source directory])
   dnl generated-files-in-srcdir is disabled by default
   AC_ARG_ENABLE(generated-files-in-srcdir, 
-[  --enable-generated-files-in-srcdir
-                          put copies of generated files in source dir
-                          intended for creating source tarballs for users
-                          without texinfo bison or flex.],
+    [AS_HELP_STRING([--enable-generated-files-in-srcdir],
+		    [put copies of generated files in source dir
+		     intended for creating source tarballs for users
+		     without texinfo bison or flex])],
       generated_files_in_srcdir=$enableval,
       generated_files_in_srcdir=no)
 
@@ -185,13 +186,13 @@  AC_SUBST(GENINSRC)
 
 # With GNU ld
 AC_ARG_WITH(gnu-ld,
-[  --with-gnu-ld           arrange to work with GNU ld.],
+[AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 gnu_ld_flag="$with_gnu_ld",
 gnu_ld_flag=no)
 
 # With pre-defined ld
 AC_ARG_WITH(ld,
-[  --with-ld               arrange to use the specified ld (full pathname)],
+[AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 DEFAULT_LINKER="$with_ld")
 if test x"${DEFAULT_LINKER+set}" = x"set"; then
   if test ! -x "$DEFAULT_LINKER"; then
@@ -219,7 +220,7 @@  fi
 
 # With demangler in GNU ld
 AC_ARG_WITH(demangler-in-ld,
-[  --with-demangler-in-ld  try to use demangler in GNU ld.],
+[AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 demangler_in_ld="$with_demangler_in_ld",
 demangler_in_ld=no)
 
@@ -229,12 +230,12 @@  demangler_in_ld=no)
 
 # With GNU as
 AC_ARG_WITH(gnu-as,
-[  --with-gnu-as           arrange to work with GNU as],
+[AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 gas_flag="$with_gnu_as",
 gas_flag=no)
 
 AC_ARG_WITH(as,
-[  --with-as               arrange to use the specified as (full pathname)],
+[AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 DEFAULT_ASSEMBLER="$with_as")
 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
   if test ! -x "$DEFAULT_ASSEMBLER"; then
@@ -359,12 +360,12 @@  if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 fi
 
 AC_ARG_ENABLE(checking,
-[  --enable-checking[=LIST]
-			  enable expensive run-time checks.  With LIST,
-			  enable only specific categories of checks.
-			  Categories are: yes,no,all,none,release.
-			  Flags are: assert,df,fold,gc,gcac,gimple,misc,
-			  rtlflag,rtl,runtime,tree,valgrind,types.],
+[AS_HELP_STRING([[--enable-checking[=LIST]]],
+		[enable expensive run-time checks.  With LIST,
+		 enable only specific categories of checks.
+		 Categories are: yes,no,all,none,release.
+		 Flags are: assert,df,fold,gc,gcac,gimple,misc,
+		 rtlflag,rtl,runtime,tree,valgrind,types])],
 [ac_checking_flags="${enableval}"],[
 # Determine the default checks.
 if test x$is_release = x ; then
@@ -547,12 +548,12 @@  AC_SUBST(valgrind_command)
 
 # Enable code coverage collection
 AC_ARG_ENABLE(coverage,
-[  --enable-coverage[=LEVEL]
-			  enable compiler's code coverage collection.
-			  Use to measure compiler performance and locate
-			  unused parts of the compiler. With LEVEL, specify
-			  optimization. Values are opt, noopt,
-			  default is noopt],
+[AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
+		[enable compiler's code coverage collection.
+		 Use to measure compiler performance and locate
+		 unused parts of the compiler. With LEVEL, specify
+		 optimization. Values are opt, noopt,
+		 default is noopt])],
 [case "${enableval}" in
   yes|noopt)
     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
@@ -572,7 +573,8 @@  esac],
 AC_SUBST(coverage_flags)
 
 AC_ARG_ENABLE(gather-detailed-mem-stats, 
-[  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
+[AS_HELP_STRING([--enable-gather-detailed-mem-stats],
+		[enable detailed memory allocation stats gathering])], [],
 [enable_gather_detailed_mem_stats=no])
 if test x$enable_gather_detailed_mem_stats = xyes ; then
   AC_DEFINE(GATHER_STATISTICS, 1,
@@ -585,7 +587,8 @@  fi
 
 # See if we are building gcc with C++.
 AC_ARG_ENABLE(build-with-cxx,
-[  --enable-build-with-cxx build with C++ compiler instead of C compiler],
+[AS_HELP_STRING([--enable-build-with-cxx],
+		[build with C++ compiler instead of C compiler])],
 ENABLE_BUILD_WITH_CXX=$enableval,
 ENABLE_BUILD_WITH_CXX=no)
 AC_SUBST(ENABLE_BUILD_WITH_CXX)
@@ -596,19 +599,21 @@  fi
 
 # With stabs
 AC_ARG_WITH(stabs,
-[  --with-stabs            arrange to use stabs instead of host debug format],
+[AS_HELP_STRING([--with-stabs],
+		[arrange to use stabs instead of host debug format])],
 stabs="$with_stabs",
 stabs=no)
 
 # Determine whether or not multilibs are enabled.
 AC_ARG_ENABLE(multilib,
-[  --enable-multilib       enable library support for multiple ABIs],
+[AS_HELP_STRING([--enable-multilib],
+		[enable library support for multiple ABIs])],
 [], [enable_multilib=yes])
 AC_SUBST(enable_multilib)
 
 # Enable __cxa_atexit for C++.
 AC_ARG_ENABLE(__cxa_atexit,
-[  --enable-__cxa_atexit   enable __cxa_atexit for C++],
+[AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 [], [])
 
 # Enable C extension for decimal float if target supports it.
@@ -628,9 +633,9 @@  point format instead of DPD])
 
 # Enable C extension for fixed-point arithmetic.
 AC_ARG_ENABLE(fixed-point,
-[  --enable-fixed-point    enable fixed-point arithmetic extension to C],
-[
-],
+[AS_HELP_STRING([--enable-fixed-point],
+		[enable fixed-point arithmetic extension to C])],
+[],
 [
   case $target in
     mips*-*-*)
@@ -660,13 +665,15 @@  AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 # Pass with no value to take the default
 # Pass with a value to specify a thread package
 AC_ARG_ENABLE(threads,
-[  --enable-threads        enable thread usage for target GCC
-  --enable-threads=LIB    use LIB thread package for target GCC],,
+[AS_HELP_STRING([[--enable-threads[=LIB]]],
+		[enable thread usage for target GCC,
+		 using LIB thread package])],,
 [enable_threads=''])
 
 AC_ARG_ENABLE(tls,
-[  --enable-tls            enable or disable generation of tls code
-                          overriding the assembler check for tls support],
+[AS_HELP_STRING([--enable-tls],
+		[enable or disable generation of tls code
+                 overriding the assembler check for tls support])],
 [
   case $enable_tls in
     yes | no) ;;
@@ -676,8 +683,9 @@  Valid choices are 'yes' and 'no'.]) ;;
 ], [enable_tls=''])
 
 AC_ARG_ENABLE(objc-gc,
-[  --enable-objc-gc	  enable the use of Boehm's garbage collector with
-			  the GNU Objective-C runtime],
+[AS_HELP_STRING([--enable-objc-gc],
+		[enable the use of Boehm's garbage collector with
+		 the GNU Objective-C runtime])],
 if test x$enable_objc_gc = xno; then
 	objc_boehm_gc=''
 else
@@ -686,12 +694,12 @@  fi,
 objc_boehm_gc='')
 
 AC_ARG_WITH(dwarf2,
-[  --with-dwarf2           force the default debug format to be DWARF 2],
+[AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 dwarf2="$with_dwarf2",
 dwarf2=no)
 
 AC_ARG_ENABLE(shared,
-[  --disable-shared        don't provide a shared libgcc],
+[AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 [
   case $enable_shared in
   yes | no) ;;
@@ -710,11 +718,12 @@  AC_ARG_ENABLE(shared,
 AC_SUBST(enable_shared)
 
 AC_ARG_WITH(build-sysroot, 
-  [  --with-build-sysroot=sysroot
-                          use sysroot as the system root during the build])
+  [AS_HELP_STRING([--with-build-sysroot=sysroot],
+                  [use sysroot as the system root during the build])])
 
 AC_ARG_WITH(sysroot,
-[  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
+[AS_HELP_STRING([[--with-sysroot[=DIR]]],
+		[search for usr/lib, usr/include, et al, within DIR])],
 [
  case ${with_sysroot} in
  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
@@ -766,7 +775,7 @@  ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 # Sanity check enable_languages in case someone does not run the toplevel
 # configure # script.
 AC_ARG_ENABLE(languages,
-[  --enable-languages=LIST specify which front-ends to build],
+[AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 [case ,${enable_languages}, in
        ,,|,yes,)
 		# go safe -- we cannot be much sure without the toplevel
@@ -786,7 +795,7 @@  esac],
 [enable_languages=c])
 
 AC_ARG_WITH(multilib-list,
-[  --with-multilib-list    Select multilibs (SH only)],
+[AS_HELP_STRING([--with-multilib-list], [select multilibs (SH only)])],
 :,
 with_multilib_list=default)
 
@@ -1138,8 +1147,8 @@  AC_SUBST(objext)
 
 # With Setjmp/Longjmp based exception handling.
 AC_ARG_ENABLE(sjlj-exceptions,
-[  --enable-sjlj-exceptions
-                          arrange to use setjmp/longjmp exception handling],
+[AS_HELP_STRING([--enable-sjlj-exceptions],
+                [arrange to use setjmp/longjmp exception handling])],
 [case $target in
   *-*-hpux10*)
     if test $enableval != yes; then
@@ -1526,23 +1535,25 @@  case "$LIBINTL" in *$LIBICONV*)
 esac
 
 AC_ARG_ENABLE(secureplt,
-[  --enable-secureplt      enable -msecure-plt by default for PowerPC],
+[AS_HELP_STRING([--enable-secureplt],
+		[enable -msecure-plt by default for PowerPC])],
 [], [])
 
 AC_ARG_ENABLE(leading-mingw64-underscores,
   AS_HELP_STRING([--enable-leading-mingw64-underscores],
-                 [Enable leading underscores on 64 bit mingw targets]),
+                 [enable leading underscores on 64 bit mingw targets]),
   [],[])
 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
     [Define if we should use leading underscore on 64 bit mingw targets])])
 
 AC_ARG_ENABLE(cld,
-[  --enable-cld            enable -mcld by default for 32bit x86], [],
+[AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
 [enable_cld=no])
 
 AC_ARG_ENABLE(frame-pointer,
-[  --enable-frame-pointer  enable -fno-omit-frame-pointer by default for 32bit x86], [],
+[AS_HELP_STRING([--enable-frame-pointer],
+		[enable -fno-omit-frame-pointer by default for 32bit x86])], [],
 [
 case $target_os in
 linux* | darwin[[8912]]*)
@@ -1558,13 +1569,13 @@  esac
 
 # Windows32 Registry support for specifying GCC installation paths.
 AC_ARG_ENABLE(win32-registry,
-[  --disable-win32-registry
-                          disable lookup of installation paths in the
-                          Registry on Windows hosts
-  --enable-win32-registry enable registry lookup (default)
-  --enable-win32-registry=KEY
-                          use KEY instead of GCC version as the last portion
-                          of the registry key],,)
+[AS_HELP_STRING([--disable-win32-registry],
+                [disable lookup of installation paths in the
+                 Registry on Windows hosts])
+AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
+AS_HELP_STRING([--enable-win32-registry=KEY],
+               [use KEY instead of GCC version as the last portion
+                of the registry key])],,)
 
 case $host_os in
   win32 | pe | cygwin* | mingw32* | uwin*)
@@ -1947,7 +1958,7 @@  fi])
 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
 PLUGIN_LD=`basename $gcc_cv_ld`
 AC_ARG_WITH(plugin-ld,
-[  --with-plugin-ld=[[ARG]]  specify the plugin linker],
+[AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
 [if test x"$withval" != x; then
    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
    PLUGIN_LD="$withval"
@@ -4287,8 +4298,8 @@  if test x"$gcc_cv_ld_buildid" = xyes; then
 fi
 
 AC_ARG_ENABLE(linker-build-id,
-[  --enable-linker-build-id
-                          compiler will always pass --build-id to linker],
+[AS_HELP_STRING([--enable-linker-build-id],
+                [compiler will always pass --build-id to linker])],
 [],
 enable_linker_build_id=no)
 
@@ -4429,7 +4440,8 @@  case "$target" in
   s390*-*-linux* | \
   alpha*-*-linux*)
     AC_ARG_WITH(long-double-128,
-[  --with-long-double-128  Use 128-bit long double by default.],
+      [AS_HELP_STRING([--with-long-double-128],
+		      [use 128-bit long double by default])],
       gcc_cv_target_ldbl128="$with_long_double_128",
       [[gcc_cv_target_ldbl128=no
       grep '^[ 	]*#[ 	]*define[ 	][ 	]*__LONG_DOUBLE_MATH_OPTIONAL' \
@@ -4466,8 +4478,9 @@  AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
 
 # Find out what GC implementation we want, or may, use.
 AC_ARG_WITH(gc,
-[  --with-gc={page,zone}   choose the garbage collection mechanism to use
-                          with the compiler],
+[AS_HELP_STRING([--with-gc={page,zone}],
+		[choose the garbage collection mechanism to use
+                 with the compiler])],
 [case "$withval" in
   page)
     GGC=ggc-$withval
@@ -4495,7 +4508,7 @@  AC_SUBST(HOST_LIBS)
 zlibdir=-L../zlib
 zlibinc="-I\$(srcdir)/../zlib"
 AC_ARG_WITH(system-zlib,
-[  --with-system-zlib      use installed libz],
+[AS_HELP_STRING([--with-system-zlib], [use installed libz])],
 zlibdir=
 zlibinc=
 )
@@ -4507,9 +4520,9 @@  dnl Very limited version of automake's enable-maintainer-mode
 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
   dnl maintainer-mode is disabled by default
   AC_ARG_ENABLE(maintainer-mode,
-[  --enable-maintainer-mode
-                          enable make rules and dependencies not useful
-                          (and sometimes confusing) to the casual installer],
+[AS_HELP_STRING([--enable-maintainer-mode],
+                [enable make rules and dependencies not useful
+                 (and sometimes confusing) to the casual installer])],
       maintainer_mode=$enableval,
       maintainer_mode=no)
 
@@ -4714,12 +4727,12 @@  AC_SUBST(dollar)
 # Find a directory in which to install a shared libgcc.
 
 AC_ARG_ENABLE(version-specific-runtime-libs,
-[  --enable-version-specific-runtime-libs
-                          specify that runtime libraries should be
-                          installed in a compiler-specific directory])
+[AS_HELP_STRING([--enable-version-specific-runtime-libs],
+                [specify that runtime libraries should be
+                 installed in a compiler-specific directory])])
 
 AC_ARG_WITH(slibdir,
-[  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
+[AS_HELP_STRING([--with-slibdir=DIR], [shared libraries in DIR @<:@LIBDIR@:>@])],
 slibdir="$with_slibdir",
 if test "${enable_version_specific_runtime_libs+set}" = set; then
   slibdir='$(libsubdir)'
@@ -4827,7 +4840,7 @@  fi
 
 # Check for plugin support
 AC_ARG_ENABLE(plugin,
-[  --enable-plugin         enable plugin support],
+[AS_HELP_STRING([--enable-plugin], [enable plugin support])],
 enable_plugin=$enableval,
 enable_plugin=yes; default_plugin=yes)