Patchwork [Ada] Implementation of AI05-0151: additional uses for incomplete types

Oct. 11, 2010, 10:13 a.m.

AI05-0151 extends the use of incomplete types, both as limited and non-limited
views. Tagged incomplete types can now appear in all profiles in declarations
and bodies. Incomplete untagged types can appear in all basic declarations.

This patch also fixes a visibility problem in the implementation of limited+
clauses, which allowed non-limited views to become improperly visible.

Compiling and executing proc.adb in Ada2012 mode must yield:

MT called with  15
Inner called with  111
MT called with  15
Inner called with  111
MT called with  15
Inner called with  111
---

with Q; with R;
procedure Proc is
   Obj_T : Q.Acc_T := R.Create (15);
begin
   Q.MT (Obj_T.all);
   Q.RMT (Obj_T.all);
   Q.Ptr (Obj_T.All);
end;
---
package P is
    type T is null record;     --  untagged

    type TT is tagged record   --  tagged
       Value : Integer;
    end record;
end P;
---
with Text_IO; use Text_IO;
with R; use R;
-- NOTE: no "with" of P here
package body Q is

   --  untagged : must be rejected in a body
   --  procedure M (X : P.T) is
   --     Y : Acc;
   --  begin
   --     Y := Create (15);
   --     Put_Line ("M called");
   --  end;  

   procedure MT(X : P.TT) is
      Y : Acc_T := Create (111);

      procedure Inner (Z : P.TT) is
      begin
      Put_Line ("Inner called with " & integer'image (Value (Z)));
      end Inner;

   begin
      Put_Line ("MT called with " & integer'image (Value (X)));
      Inner (Y.all);
   end;  
end Q;
---
limited with P;
package Q is
   --  Untagged records.

   type Acc is access P.T;
   type Acc_Sub is access procedure (X : P.T);
   type Acc_Ret is access function (X : Integer) return P.T;

   --  Ptr : Acc_Sub := M'Access;

   --  Tagged records.

   procedure MT (X : P.TT);
   type Acc_T is access P.TT;
   type Acc_SubT is access procedure (X : P.TT);
   type Acc_RetT is access function (X : Integer) return P.TT;
   procedure RMT (X : P.TT) renames MT;
   Ptr : Acc_SubT := MT'access;
end Q;
---
with P; use P;
package body  R is
  Obj : Acc := new T;
  Obj_T : Acc_T := new TT'(Value => 111);
  function Create (X : Integer) return Acc is
  begin
      return Obj;
  end;

  function Create (X : Integer) return Acc_T is
     It : Acc_T := new TT'(Value => X);
  begin
     return It;
  end;

  function Value (Obj : TT) return Integer is
  begin
      return Obj.Value;
  end;
end;
---
with P;
with Q; use Q;
package R is

  --  constructors for types declared in P.

  function Create (X : Integer) return Acc;
  function Create (X : Integer) return Acc_T;
  function Value (Obj : P.TT) return Integer;
end;

Tested on x86_64-pc-linux-gnu, committed on trunk

2010-10-11  Ed Schonberg  <schonberg@adacore.com>

	* sem_ch3.adb (Access_Subprogram_Declaration): In Ada2012 an incomplete
	type is legal in the profile of any basic declaration.
	* sem_ch6.adb (Analyze_Return_Type, Process_Formals): In Ada2012 an
	incomplete type, including a limited view of a type, is legal in the
	profile of any subprogram declaration.
	If the type is tagged, its use is also legal in a body.
	* sem_ch10.adb (Install_Limited_With_Clause): Do not process context
	item if misplaced.
	(Install_Limited_Withed_Unit): Refine legality checks when both the
	limited and the non-limited view of a package are visible in the context
	of a unit.
	If this is not an error case, the limited view is ignored.
	freeze.adb (Freeze_Entity): In Ada2012, an incomplete type is legal in
	access to subprogram declarations

Submitter	Arnaud Charlet
Date	Oct. 11, 2010, 10:13 a.m.
Message ID	<20101011101355.GA29986@adacore.com>
Download	mbox \| patch
Permalink	/patch/67403/
State	New
Headers	show Return-Path: <gcc-patches-return-275051-incoming=patchwork.ozlabs.org@gcc.gnu.org> Date: Mon, 11 Oct 2010 12:13:55 +0200 From: Arnaud Charlet <charlet@adacore.com> To: gcc-patches@gcc.gnu.org Cc: Ed Schonberg <schonberg@adacore.com> Subject: [Ada] Implementation of AI05-0151: additional uses for incomplete types Message-ID: <20101011101355.GA29986@adacore.com> Mime-Version: 1.0 Content-Type: multipart/mixed; boundary="Nq2Wo0NMKNjxTN9z" Content-Disposition: inline User-Agent: Mutt/1.5.9i Mailing-List: contact gcc-patches-help@gcc.gnu.org; run by ezmlm Precedence: bulk Sender: gcc-patches-owner@gcc.gnu.org

Patchwork [Ada] Implementation of AI05-0151: additional uses for incomplete types

Comments

Patch