Patchwork [toplevel] Use AS_HELP_STRING in configure.ac

login
register
mail settings
Submitter Andreas Schwab
Date Sept. 30, 2010, 11:44 a.m.
Message ID <m3pqvv4fs4.fsf@hase.home>
Download mbox | patch
Permalink /patch/66148/
State New
Headers show

Comments

Andreas Schwab - Sept. 30, 2010, 11:44 a.m.
This patch makes AC_ARG_ENABLE/AC_ARG_WITH to use AS_HELP_STRING
throughout for the help string. OK?

Andreas.

2010-09-30  Andreas Schwab  <schwab@redhat.com>

	* configure.ac: Use AS_HELP_STRING throughout.
	* configure: Regenerate.

Patch

Index: configure
===================================================================
--- configure	(revision 164748)
+++ configure	(working copy)
@@ -1487,74 +1487,86 @@ 
   --enable-libada         build libada directory
   --enable-libssp         build libssp directory
   --enable-build-with-cxx build with C++ compiler instead of C compiler
-  --disable-ppl-version-check    disable check for PPL version
-  --disable-cloog-version-check  disable check for CLooG version
+  --disable-ppl-version-check
+                          disable check for PPL version
+  --disable-cloog-version-check
+                          disable check for CLooG version
   --enable-lto            enable link time optimization support
-  --enable-stage1-languages[=all]   choose additional languages to build during
-                          stage1.  Mostly useful for compiler development.
-  --enable-objc-gc        enable use of Boehm's garbage collector with the
-                          GNU Objective-C runtime
+  --enable-stage1-languages[=all]
+                          choose additional languages to build during stage1.
+                          Mostly useful for compiler development
+  --enable-objc-gc        enable use of Boehm's garbage collector with the GNU
+                          Objective-C runtime
   --enable-bootstrap      enable bootstrapping [yes if native build]
   --enable-serial-[{host,target,build}-]configure
-                          force sequential configuration of
-                          sub-packages for the host, target or build
-                          machine, or all sub-packages
-  --enable-maintainer-mode enable make rules and dependencies not useful
-                          (and sometimes confusing) to the casual installer
-  --enable-stage1-checking[=all]   choose additional checking for stage1
-                          of the compiler
+                          force sequential configuration of sub-packages for
+                          the host, target or build machine, or all
+                          sub-packages
+  --enable-maintainer-mode
+                          enable make rules and dependencies not useful (and
+                          sometimes confusing) to the casual installer
+  --enable-stage1-checking[=all]
+                          choose additional checking for stage1 of the
+                          compiler
   --enable-werror         enable -Werror in bootstrap stage2 and later
 
 Optional Packages:
   --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
   --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)
   --with-build-libsubdir=DIR  Directory where to find libraries for build system
-  --with-mpc=PATH        specify prefix directory for installed MPC package.
-                          Equivalent to --with-mpc-include=PATH/include
-                          plus --with-mpc-lib=PATH/lib
-  --with-mpc-include=PATH
-                          specify directory for installed MPC include files
-  --with-mpc-lib=PATH    specify directory for the installed MPC library
+  --with-mpc=PATH         specify prefix directory for installed MPC package.
+                          Equivalent to --with-mpc-include=PATH/include plus
+                          --with-mpc-lib=PATH/lib
+  --with-mpc-include=PATH specify directory for installed MPC include files
+  --with-mpc-lib=PATH     specify directory for the installed MPC library
   --with-mpfr-dir=PATH    this option has been REMOVED
   --with-mpfr=PATH        specify prefix directory for installed MPFR package.
-                          Equivalent to --with-mpfr-include=PATH/include
-                          plus --with-mpfr-lib=PATH/lib
+                          Equivalent to --with-mpfr-include=PATH/include plus
+                          --with-mpfr-lib=PATH/lib
   --with-mpfr-include=PATH
                           specify directory for installed MPFR include files
   --with-mpfr-lib=PATH    specify directory for the installed MPFR library
   --with-gmp-dir=PATH     this option has been REMOVED
-  --with-gmp=PATH         specify prefix directory for the installed GMP package.
-                          Equivalent to --with-gmp-include=PATH/include
-                          plus --with-gmp-lib=PATH/lib
+  --with-gmp=PATH         specify prefix directory for the installed GMP
+                          package. Equivalent to
+                          --with-gmp-include=PATH/include plus
+                          --with-gmp-lib=PATH/lib
   --with-gmp-include=PATH specify directory for installed GMP include files
   --with-gmp-lib=PATH     specify directory for the installed GMP library
-  --with-host-libstdcxx=L Use linker arguments L to link with libstdc++
-                          when linking with PPL
-  --with-stage1-ldflags=FLAGS Linker flags for stage1
-  -with-stage1-libs=LIBS      Libraries for stage1
-  --with-boot-libs=LIBS     Libraries for stage2 and later
-  --with-boot-ldflags=FLAGS Linker flags for stage2 and later
-  --with-ppl=PATH         Specify prefix directory for the installed PPL package
-                          Equivalent to --with-ppl-include=PATH/include
-                          plus --with-ppl-lib=PATH/lib
-  --with-ppl-include=PATH Specify directory for installed PPL include files
-  --with-ppl-lib=PATH     Specify the directory for the installed PPL library
-  --with-cloog=PATH       Specify prefix directory for the installed CLooG-PPL package
-                          Equivalent to --with-cloog-include=PATH/include
-                          plus --with-cloog-lib=PATH/lib
-  --with-cloog-include=PATH Specify directory for installed CLooG include files
-  --with-cloog-lib=PATH   Specify the directory for the installed CLooG library
-  --with-libelf=PATH       Specify prefix directory for the installed libelf package
-                          Equivalent to --with-libelf-include=PATH/include
-                          plus --with-libelf-lib=PATH/lib
-  --with-libelf-include=PATH Specify directory for installed libelf include files
-  --with-libelf-lib=PATH   Specify the directory for the installed libelf library
+  --with-host-libstdcxx=L use linker arguments L to link with libstdc++ when
+                          linking with PPL
+  --with-stage1-ldflags=FLAGS
+                          linker flags for stage1
+  --with-stage1-libs=LIBS libraries for stage1
+  --with-boot-libs=LIBS   libraries for stage2 and later
+  --with-boot-ldflags=FLAGS
+                          linker flags for stage2 and later
+  --with-ppl=PATH         specify prefix directory for the installed PPL
+                          package. Equivalent to
+                          --with-ppl-include=PATH/include plus
+                          --with-ppl-lib=PATH/lib
+  --with-ppl-include=PATH specify directory for installed PPL include files
+  --with-ppl-lib=PATH     specify directory for the installed PPL library
+  --with-cloog=PATH       specify prefix directory for the installed CLooG-PPL
+                          package. Equivalent to
+                          --with-cloog-include=PATH/include plus
+                          --with-cloog-lib=PATH/lib
+  --with-cloog-include=PATH
+                          specify directory for installed CLooG include files
+  --with-cloog-lib=PATH   specify directory for the installed CLooG library
+  --with-libelf=PATH      specify prefix directory for the installed libelf
+                          package. Equivalent to
+                          --with-libelf-include=PATH/include plus
+                          --with-libelf-lib=PATH/lib
+  --with-libelf-include=PATH
+                          specify directory for installed libelf include files
+  --with-libelf-lib=PATH  specify directory for the installed libelf library
   --with-build-sysroot=SYSROOT
                           use sysroot as the system root during the build
   --with-debug-prefix-map='A=B C=D ...'
-                             map A to B, C to D ... in debug information
---with-build-config='NAME NAME2...'
-                          Use config/NAME.mk build configuration
+                          map A to B, C to D ... in debug information
+  --with-build-config='NAME NAME2...'
+                          use config/NAME.mk build configuration
   --with-build-time-tools=PATH
                           use given path to find target tools during the build
 
Index: configure.ac
===================================================================
--- configure.ac	(revision 164748)
+++ configure.ac	(working copy)
@@ -322,7 +322,8 @@ 
 #   --enable-gold=both/gold	Build both gold and ld, gold is default, ld is renamed ld.bfd
 
 AC_ARG_ENABLE(gold,
-[[  --enable-gold[=ARG]     build gold [ARG={both}[/{gold,ld}]]]],
+[AS_HELP_STRING([[--enable-gold[=ARG]]],
+		[build gold @<:@ARG={both}@<:@/{gold,ld}@:>@@:>@])],
 ENABLE_GOLD=$enableval,
 ENABLE_GOLD=no)
   case "${ENABLE_GOLD}" in
@@ -417,7 +418,7 @@ 
 
 
 AC_ARG_ENABLE(libada,
-[  --enable-libada         build libada directory],
+[AS_HELP_STRING([--enable-libada], [build libada directory])],
 ENABLE_LIBADA=$enableval,
 ENABLE_LIBADA=yes)
 if test "${ENABLE_LIBADA}" != "yes" ; then
@@ -425,7 +426,7 @@ 
 fi
 
 AC_ARG_ENABLE(libssp,
-[  --enable-libssp         build libssp directory],
+[AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 ENABLE_LIBSSP=$enableval,
 ENABLE_LIBSSP=yes)
 
@@ -1248,7 +1249,8 @@ 
 
 # See if we are building gcc with C++.
 AC_ARG_ENABLE(build-with-cxx,
-[  --enable-build-with-cxx build with C++ compiler instead of C compiler],
+[AS_HELP_STRING([--enable-build-with-cxx],
+		[build with C++ compiler instead of C compiler])],
 ENABLE_BUILD_WITH_CXX=$enableval,
 ENABLE_BUILD_WITH_CXX=no)
 
@@ -1262,12 +1264,17 @@ 
 
 # Specify a location for mpc
 # check for this first so it ends up on the link line before mpfr.
-AC_ARG_WITH(mpc, [  --with-mpc=PATH        specify prefix directory for installed MPC package.
-                          Equivalent to --with-mpc-include=PATH/include
-                          plus --with-mpc-lib=PATH/lib])
-AC_ARG_WITH(mpc_include, [  --with-mpc-include=PATH
-                          specify directory for installed MPC include files])
-AC_ARG_WITH(mpc_lib, [  --with-mpc-lib=PATH    specify directory for the installed MPC library])
+AC_ARG_WITH(mpc,
+[AS_HELP_STRING([--with-mpc=PATH],
+		[specify prefix directory for installed MPC package.
+		 Equivalent to --with-mpc-include=PATH/include
+		 plus --with-mpc-lib=PATH/lib])])
+AC_ARG_WITH(mpc_include,
+[AS_HELP_STRING([--with-mpc-include=PATH],
+		[specify directory for installed MPC include files])])
+AC_ARG_WITH(mpc_lib,
+[AS_HELP_STRING([--with-mpc-lib=PATH],
+		[specify directory for the installed MPC library])])
 
 if test "x$with_mpc" != x; then
   gmplibs="-L$with_mpc/lib $gmplibs"
@@ -1291,16 +1298,22 @@ 
 
 # Specify a location for mpfr
 # check for this first so it ends up on the link line before gmp.
-AC_ARG_WITH(mpfr-dir, [  --with-mpfr-dir=PATH    this option has been REMOVED],
-  AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
-Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH]))
+AC_ARG_WITH(mpfr-dir,
+[AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
+[AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
+Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
 
-AC_ARG_WITH(mpfr, [  --with-mpfr=PATH        specify prefix directory for installed MPFR package.
-                          Equivalent to --with-mpfr-include=PATH/include
-                          plus --with-mpfr-lib=PATH/lib])
-AC_ARG_WITH(mpfr_include, [  --with-mpfr-include=PATH
-                          specify directory for installed MPFR include files])
-AC_ARG_WITH(mpfr_lib, [  --with-mpfr-lib=PATH    specify directory for the installed MPFR library])
+AC_ARG_WITH(mpfr,
+[AS_HELP_STRING([--with-mpfr=PATH],
+		[specify prefix directory for installed MPFR package.
+		 Equivalent to --with-mpfr-include=PATH/include
+		 plus --with-mpfr-lib=PATH/lib])])
+AC_ARG_WITH(mpfr_include,
+[AS_HELP_STRING([--with-mpfr-include=PATH],
+		[specify directory for installed MPFR include files])])
+AC_ARG_WITH(mpfr_lib,
+[AS_HELP_STRING([--with-mpfr-lib=PATH],
+		[specify directory for the installed MPFR library])])
 
 if test "x$with_mpfr" != x; then
   gmplibs="-L$with_mpfr/lib $gmplibs"
@@ -1324,15 +1337,22 @@ 
 fi
 
 # Specify a location for gmp
-AC_ARG_WITH(gmp-dir, [  --with-gmp-dir=PATH     this option has been REMOVED],
-  AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
-Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH]))
+AC_ARG_WITH(gmp-dir,
+[AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
+[AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
+Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
 
-AC_ARG_WITH(gmp, [  --with-gmp=PATH         specify prefix directory for the installed GMP package.
-                          Equivalent to --with-gmp-include=PATH/include
-                          plus --with-gmp-lib=PATH/lib])
-AC_ARG_WITH(gmp_include, [  --with-gmp-include=PATH specify directory for installed GMP include files])
-AC_ARG_WITH(gmp_lib, [  --with-gmp-lib=PATH     specify directory for the installed GMP library])
+AC_ARG_WITH(gmp,
+[AS_HELP_STRING([--with-gmp=PATH],
+		[specify prefix directory for the installed GMP package.
+		 Equivalent to --with-gmp-include=PATH/include
+		 plus --with-gmp-lib=PATH/lib])])
+AC_ARG_WITH(gmp_include,
+[AS_HELP_STRING([--with-gmp-include=PATH],
+		[specify directory for installed GMP include files])])
+AC_ARG_WITH(gmp_lib,
+[AS_HELP_STRING([--with-gmp-lib=PATH],
+		[specify directory for the installed GMP library])])
 
 
 if test "x$with_gmp" != x; then
@@ -1464,8 +1484,10 @@ 
 AC_SUBST(extra_mpc_mpfr_configure_flags)
 
 # Allow host libstdc++ to be specified for static linking with PPL.
-AC_ARG_WITH(host-libstdcxx, [  --with-host-libstdcxx=L Use linker arguments L to link with libstdc++
-                          when linking with PPL])
+AC_ARG_WITH(host-libstdcxx,
+[AS_HELP_STRING([--with-host-libstdcxx=L],
+		[use linker arguments L to link with libstdc++
+		 when linking with PPL])])
 
 case $with_host_libstdcxx in
   no|yes)
@@ -1475,7 +1497,7 @@ 
 
 # Linker flags to use for stage1 or when not boostrapping.
 AC_ARG_WITH(stage1-ldflags,
-[  --with-stage1-ldflags=FLAGS Linker flags for stage1],
+[AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
 [if test "$withval" = "no" -o "$withval" = "yes"; then
    stage1_ldflags=
  else
@@ -1486,7 +1508,7 @@ 
 
 # Libraries to use for stage1 or when not bootstrapping.
 AC_ARG_WITH(stage1-libs,
-[  -with-stage1-libs=LIBS      Libraries for stage1],
+[AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
 [if test "$withval" = "no" -o "$withval" = "yes"; then
    stage1_libs=
  else
@@ -1498,7 +1520,7 @@ 
 # Libraries to use for stage2 and later builds.  This defaults to the
 # argument passed to --with-host-libstdcxx.
 AC_ARG_WITH(boot-libs,
-[  --with-boot-libs=LIBS     Libraries for stage2 and later],
+[AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
 [if test "$withval" = "no" -o "$withval" = "yes"; then
    poststage1_libs=
  else
@@ -1509,7 +1531,8 @@ 
 
 # Linker flags to use for stage2 and later builds.
 AC_ARG_WITH(boot-ldflags,
-[  --with-boot-ldflags=FLAGS Linker flags for stage2 and later],
+[AS_HELP_STRING([--with-boot-ldflags=FLAGS],
+		[linker flags for stage2 and later])],
 [if test "$withval" = "no" -o "$withval" = "yes"; then
    poststage1_ldflags=
  else
@@ -1528,11 +1551,17 @@ 
 ppllibs=" -lppl_c -lppl -lgmpxx"
 pplinc=
 
-AC_ARG_WITH(ppl, [  --with-ppl=PATH         Specify prefix directory for the installed PPL package
-                          Equivalent to --with-ppl-include=PATH/include
-                          plus --with-ppl-lib=PATH/lib])
-AC_ARG_WITH(ppl_include, [  --with-ppl-include=PATH Specify directory for installed PPL include files])
-AC_ARG_WITH(ppl_lib, [  --with-ppl-lib=PATH     Specify the directory for the installed PPL library])
+AC_ARG_WITH(ppl,
+[AS_HELP_STRING([--with-ppl=PATH],
+		[specify prefix directory for the installed PPL package.
+		 Equivalent to --with-ppl-include=PATH/include
+		 plus --with-ppl-lib=PATH/lib])])
+AC_ARG_WITH(ppl_include,
+[AS_HELP_STRING([--with-ppl-include=PATH],
+		[specify directory for installed PPL include files])])
+AC_ARG_WITH(ppl_lib,
+[AS_HELP_STRING([--with-ppl-lib=PATH],
+		[specify directory for the installed PPL library])])
 
 case $with_ppl in 
   no)
@@ -1558,7 +1587,8 @@ 
 fi
 
 AC_ARG_ENABLE(ppl-version-check,
-[  --disable-ppl-version-check    disable check for PPL version],
+[AS_HELP_STRING([--disable-ppl-version-check],
+		[disable check for PPL version])],
 ENABLE_PPL_CHECK=$enableval,
 ENABLE_PPL_CHECK=yes)
 
@@ -1583,11 +1613,17 @@ 
 clooglibs=" -lcloog "
 clooginc=" -DCLOOG_PPL_BACKEND "
 
-AC_ARG_WITH(cloog, [  --with-cloog=PATH       Specify prefix directory for the installed CLooG-PPL package
-                          Equivalent to --with-cloog-include=PATH/include
-                          plus --with-cloog-lib=PATH/lib])
-AC_ARG_WITH(cloog_include, [  --with-cloog-include=PATH Specify directory for installed CLooG include files])
-AC_ARG_WITH(cloog_lib, [  --with-cloog-lib=PATH   Specify the directory for the installed CLooG library])
+AC_ARG_WITH(cloog,
+[AS_HELP_STRING([--with-cloog=PATH],
+		[specify prefix directory for the installed CLooG-PPL package.
+		 Equivalent to --with-cloog-include=PATH/include
+		 plus --with-cloog-lib=PATH/lib])])
+AC_ARG_WITH(cloog_include,
+[AS_HELP_STRING([--with-cloog-include=PATH],
+		[specify directory for installed CLooG include files])])
+AC_ARG_WITH(cloog_lib,
+[AS_HELP_STRING([--with-cloog-lib=PATH],
+		[specify directory for the installed CLooG library])])
 
 if test "x$with_ppl" = "xno"; then
   with_cloog=no
@@ -1618,7 +1654,8 @@ 
 fi
 
 AC_ARG_ENABLE(cloog-version-check,
-[  --disable-cloog-version-check  disable check for CLooG version],
+[AS_HELP_STRING([--disable-cloog-version-check],
+		[disable check for CLooG version])],
 ENABLE_CLOOG_CHECK=$enableval,
 ENABLE_CLOOG_CHECK=yes)
 
@@ -1645,20 +1682,26 @@ 
 
 # Check for LTO support.
 AC_ARG_ENABLE(lto,
-[  --enable-lto            enable link time optimization support],
+[AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
 enable_lto=$enableval,
 enable_lto=yes; default_enable_lto=yes)
 
 
 ACX_ELF_TARGET_IFELSE([if test x"$enable_lto" = x"yes" ; then
   # Make sure that libelf.h and gelf.h are available.
-  AC_ARG_WITH(libelf, [  --with-libelf=PATH       Specify prefix directory for the installed libelf package
-                          Equivalent to --with-libelf-include=PATH/include
-                          plus --with-libelf-lib=PATH/lib])
+  AC_ARG_WITH(libelf,
+  [AS_HELP_STRING([--with-libelf=PATH],
+		  [specify prefix directory for the installed libelf package.
+		   Equivalent to --with-libelf-include=PATH/include
+		   plus --with-libelf-lib=PATH/lib])])
 
-  AC_ARG_WITH(libelf_include, [  --with-libelf-include=PATH Specify directory for installed libelf include files])
+  AC_ARG_WITH(libelf_include,
+  [AS_HELP_STRING([--with-libelf-include=PATH],
+		  [specify directory for installed libelf include files])])
 
-  AC_ARG_WITH(libelf_lib, [  --with-libelf-lib=PATH   Specify the directory for the installed libelf library])
+  AC_ARG_WITH(libelf_lib,
+  [AS_HELP_STRING([--with-libelf-lib=PATH],
+		  [specify directory for the installed libelf library])])
 
   saved_CFLAGS="$CFLAGS"
   saved_CPPFLAGS="$CPPFLAGS"
@@ -2000,8 +2043,9 @@ 
   done
 
   AC_ARG_ENABLE(stage1-languages,
-[  --enable-stage1-languages@<:@=all@:>@   choose additional languages to build during
-                          stage1.  Mostly useful for compiler development.],
+  [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
+		  [choose additional languages to build during
+		  stage1.  Mostly useful for compiler development])],
   [case ,${enable_stage1_languages}, in
     ,no,|,,)
       # Set it to something that will have no effect in the loop below
@@ -2062,8 +2106,9 @@ 
 
 # Check for Boehm's garbage collector
 AC_ARG_ENABLE(objc-gc,
-[  --enable-objc-gc        enable use of Boehm's garbage collector with the
-                          GNU Objective-C runtime],
+[AS_HELP_STRING([--enable-objc-gc],
+		[enable use of Boehm's garbage collector with the
+		 GNU Objective-C runtime])],
 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
   *,objc,*:*:yes:*target-boehm-gc*)
     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
@@ -2218,8 +2263,8 @@ 
 copy_dirs=
 
 AC_ARG_WITH([build-sysroot], 
-  [  --with-build-sysroot=SYSROOT
-                          use sysroot as the system root during the build],
+  [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
+		  [use sysroot as the system root during the build])],
   [if test x"$withval" != x ; then
      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
    fi],
@@ -2227,8 +2272,8 @@ 
 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 
 AC_ARG_WITH([debug-prefix-map],
-  [  --with-debug-prefix-map='A=B C=D ...'
-                             map A to B, C to D ... in debug information],
+  [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
+		  [map A to B, C to D ... in debug information])],
   [if test x"$withval" != x; then
      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
      for debug_map in $withval; do
@@ -2657,7 +2702,8 @@ 
 # Do not nest @if/@endif pairs, because configure will not warn you at all.
 
 AC_ARG_ENABLE([bootstrap],
-[  --enable-bootstrap      enable bootstrapping @<:@yes if native build@:>@],,
+[AS_HELP_STRING([--enable-bootstrap],
+		[enable bootstrapping @<:@yes if native build@:>@])],,
 enable_bootstrap=default)
 
 # Issue errors and warnings for invalid/strange bootstrap combinations.
@@ -2726,8 +2772,8 @@ 
 AC_MSG_CHECKING(for default BUILD_CONFIG)
 
 AC_ARG_WITH([build-config],
-  [--with-build-config='NAME NAME2...'
-                          Use config/NAME.mk build configuration],
+  [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
+		  [use config/NAME.mk build configuration])],
   [case $with_build_config in
    yes) with_build_config= ;;
    no) with_build_config= BUILD_CONFIG= ;;
@@ -2812,10 +2858,10 @@ 
 # Create the serialization dependencies.  This uses a temporary file.
 
 AC_ARG_ENABLE([serial-configure],
-[  --enable-serial-@<:@{host,target,build}-@:>@configure
-                          force sequential configuration of
-                          sub-packages for the host, target or build
-                          machine, or all sub-packages])
+[AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
+		[force sequential configuration of
+		 sub-packages for the host, target or build
+		 machine, or all sub-packages])])
 
 case ${enable_serial_configure} in
   yes)
@@ -3270,8 +3316,8 @@ 
 
 # Target tools.
 AC_ARG_WITH([build-time-tools], 
-  [  --with-build-time-tools=PATH
-                          use given path to find target tools during the build],
+  [AS_HELP_STRING([--with-build-time-tools=PATH],
+		  [use given path to find target tools during the build])],
   [case x"$withval" in
      x/*) ;;
      *)
@@ -3354,8 +3400,9 @@ 
 
 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
 AC_ARG_ENABLE(maintainer-mode,
-[  --enable-maintainer-mode enable make rules and dependencies not useful
-                          (and sometimes confusing) to the casual installer],
+[AS_HELP_STRING([--enable-maintainer-mode],
+		[enable make rules and dependencies not useful
+		 (and sometimes confusing) to the casual installer])],
       USE_MAINTAINER_MODE=$enableval,
       USE_MAINTAINER_MODE=no)
 AC_MSG_RESULT($USE_MAINTAINER_MODE)
@@ -3409,8 +3456,8 @@ 
 
 # Enable --enable-checking in stage1 of the compiler.
 AC_ARG_ENABLE(stage1-checking,
-[  --enable-stage1-checking@<:@=all@:>@   choose additional checking for stage1
-                          of the compiler],
+[AS_HELP_STRING([[--enable-stage1-checking[=all]]],
+		[choose additional checking for stage1 of the compiler])],
 [stage1_checking=--enable-checking=${enable_stage1_checking}],
 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
   stage1_checking=--enable-checking=yes,types
@@ -3421,7 +3468,8 @@ 
 
 # Enable -Werror in bootstrap stage2 and later.
 AC_ARG_ENABLE(werror,
-[  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
+[AS_HELP_STRING([--enable-werror],
+		[enable -Werror in bootstrap stage2 and later])], [],
 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
   enable_werror=yes
 else