diff mbox

[3/3] syslinux: Add new recipe for syslinux

Message ID 42b3f748802aa93975527dcdbc4ef8f1f7c8aff5.1361873632.git.christian.braunersorensen@prevas.dk
State Superseded
Delegated to: Esben Haabendal
Headers show

Commit Message

christian.braunersorensen@prevas.dk Feb. 26, 2013, 10:16 a.m. UTC 
From: Christian Sørensen <christian.braunersorensen@prevas.dk>

---
 recipes/syslinux/syslinux_5.01.oe     | 59 +++++++++++++++++++++++++++++++++++
 recipes/syslinux/syslinux_5.01.oe.sig |  1 +
 2 files changed, 60 insertions(+)
 create mode 100644 recipes/syslinux/syslinux_5.01.oe
 create mode 100644 recipes/syslinux/syslinux_5.01.oe.sig
diff mbox

Patch

diff --git a/recipes/syslinux/syslinux_5.01.oe b/recipes/syslinux/syslinux_5.01.oe
new file mode 100644
index 0000000..24c8e78
--- /dev/null
+++ b/recipes/syslinux/syslinux_5.01.oe
@@ -0,0 +1,59 @@ 
+DESCRIPTION = "A multi-purpose linux bootloader"
+HOMEPAGE = "http://syslinux.zytor.com/"
+LICENSE = "GPLv2+"
+
+RECIPE_TYPES = "native machine"
+
+inherit c make auto-package-utils
+
+require conf/fetch/kernelorg.conf
+SRC_URI = "${KERNELORG_MIRROR}/linux/utils/boot/syslinux/syslinux-${PV}.tar.bz2"
+
+DEPENDS += "libuuid"
+
+EXTRA_OEMAKE = " \
+	BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \
+	DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
+"
+# syslinux uses $LD for linking, strip `-Wl,' so it can work
+export LDFLAGS = "`echo $LDFLAGS | sed 's/-Wl,//g'`"
+
+do_configure() {
+	# drop win32 targets or build fails
+	sed -e 's,win32/\S*,,g' -i Makefile
+
+	# clean installer executables included in source tarball
+	oe_runmake clean
+}
+
+do_compile() {
+	# Rebuild only the installer; keep precompiled bootloaders
+	# as per author's request (doc/distrib.txt)
+	oe_runmake CC="${CC}" -C ${S}/com32/cmenu/
+	oe_runmake CC="${CC}" installer
+}
+
+do_install() {
+	oe_runmake install INSTALLROOT="${D}"
+
+	install -d ${D}${libdir}/syslinux/
+	install -m 644 ${S}/core/ldlinux.sys ${D}${libdir}/syslinux/
+	install -m 644 ${S}/core/ldlinux.bss ${D}${libdir}/syslinux/
+}
+
+AUTO_PACKAGE_UTILS = "extlinux gethostip isohybrid isohybrid.pl \
+		keytab-lilo lss16toppm md5pass memdiskfind \
+		mkdiskimage ppmtolss16 pxelinux-options sha1pass \
+		syslinux syslinux2ansi"
+
+PACKAGES += "${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux ${PN}-misc"
+
+FILES_${PN} = "${bindir}/syslinux"
+FILES_${PN}-mbr = "${datadir}/${PN}/mbr.bin"
+FILES_${PN}-chain = "${libdir}/${PN}/chain.c32"
+FILES_${PN}-isolinux = "${libdir}/${PN}/isolinux.bin"
+FILES_${PN}-pxelinux = "${libdir}/${PN}/pxelinux.0"
+FILES_${PN}-dev += "${datadir}/${PN}/com32/lib*${SOLIBS} ${datadir}/${PN}/com32/include ${datadir}/${PN}/com32/com32.ld"
+FILES_${PN}-staticdev += "${datadir}/${PN}/com32/lib*.a ${libdir}/${PN}/com32/lib*.a"
+FILES_${PN}-misc = "${libdir}/${PN}/* ${bindir}/* ${datadir}"
+
diff --git a/recipes/syslinux/syslinux_5.01.oe.sig b/recipes/syslinux/syslinux_5.01.oe.sig
new file mode 100644
index 0000000..566fee9
--- /dev/null
+++ b/recipes/syslinux/syslinux_5.01.oe.sig
@@ -0,0 +1 @@ 
+c41eecaad46a6d90bbdc7a855a6c2561aabc1e03  syslinux-5.01.tar.bz2